メインコンテンツまでスキップ

data source で情報を参照する

このページでは、data source を使って情報を参照する方法を説明します。これは リソース別の例 にあるすべての例の基礎となります。ID を手作業でコピーする代わりに data source で参照すると、設定を変更せずに別の VPC でも動作させることができます。

前提条件​

VPC を参照する​

ほとんどのリソースには vpc_id が必要です。VPC を名前で参照します。

data "fptcloud_vpc" "example" {
name = "example-vpc"
}

vpc_id が必要な箇所では、すべて data.fptcloud_vpc.example.id を使います。この data source は、provider で宣言した tenant 内で VPC を検索します。見つからない場合、terraform plan はエラーで停止します。

flavor を参照する​

flavor は Instance の vCPU 数と RAM 容量を決定します。

ハードウェア構成で選択します。 この方法は、該当する flavor がある任意の VPC で動作します。

data "fptcloud_flavor" "medium" {
vpc_id = data.fptcloud_vpc.example.id

filter {
key = "cpu"
values = ["4"]
}
filter {
key = "memory_mb"
values = ["8192"]
}
filter {
key = "type"
values = ["VM_SIZE"]
}
}

VPC 内の flavor の正確な名前がわかっている場合は、名前で選択します。

data "fptcloud_flavor" "by_name" {
vpc_id = data.fptcloud_vpc.example.id

filter {
key = "name"
values = ["Medium-4"] # VPC にある flavor 名に置き換えます
}
}

Instance の flavor_name 引数には data.fptcloud_flavor.medium.flavors[0].name を使います。

image を参照する​

名前の一部で検索し、GPU image を除外します。

data "fptcloud_image" "ubuntu" {
vpc_id = data.fptcloud_vpc.example.id

filter {
key = "name"
values = ["UBUNTU-22.04"]
match_by = "substring"
}
filter {
key = "is_gpu"
values = ["false"]
}
}

正規表現で検索し、常に同じ image が選ばれるように並べ替えます。

data "fptcloud_image" "rocky" {
vpc_id = data.fptcloud_vpc.example.id

filter {
key = "name"
values = ["^ROCKYLINUX-9"]
match_by = "re"
}
sort {
key = "name"
direction = "desc"
}
}

Instance の image_name 引数には data.fptcloud_image.ubuntu.images[0].name を使います。

警告

実行中の Instance の image_name を変更すると、Instance が削除されてから再作成されます。image のフィルターが時間の経過とともに新しい image を返す可能性がある場合は、重要な Instance の image 名を固定してください。

storage policy を参照する​

storage policy は disk の性能レベルです。

data "fptcloud_storage_policy" "ssd" {
vpc_id = data.fptcloud_vpc.example.id

filter {
key = "name"
values = ["Premium-SSD"] # VPC にある storage policy 名に置き換えます
}
}

storage_policy_id 引数には data.fptcloud_storage_policy.ssd.storage_policies[0].id を使います。

既存のリソースを参照する​

data source を使うと、Portal で作成したリソースを Terraform の管理下に置かずに参照できます。

data "fptcloud_subnet" "shared" {
vpc_id = data.fptcloud_vpc.example.id

filter {
key = "name"
values = ["shared-subnet"]
}
}

data "fptcloud_instance" "jump_host" {
vpc_id = data.fptcloud_vpc.example.id
name = "jump-host-01"
}
  • data.fptcloud_subnet.shared.subnets[0].id は Subnet の ID を返します。
  • data.fptcloud_instance.jump_host.private_ip は Instance の private IP を返します。

一覧を表示して利用可能な値を確認する​

filter ブロックを省略して一覧全体を取得し、output で出力します。

data "fptcloud_flavor" "all" {
vpc_id = data.fptcloud_vpc.example.id
}

output "flavors" {
value = [for f in data.fptcloud_flavor.all.flavors : "${f.name}: ${f.cpu} vCPU, ${f.memory_mb} MB"]
}

terraform apply を実行して一覧を表示します。data source はデータを読み取るだけで、リソースは作成しません。

フィルターのルール​

data source fptcloud_flavor、fptcloud_image、fptcloud_storage_policy、fptcloud_subnet、fptcloud_instance_group_policy は、共通の filter ブロックと sort ブロックを使います。

要素動作
複数の filter ブロック結果はすべてのブロックに一致する必要があります。
values 内の複数の値結果はいずれか1 つの値に一致すれば十分です。
match_by = "exact"デフォルトです。文字列全体を比較し、大文字と小文字を区別しません。
match_by = "substring"文字列に検索する値が含まれているかを比較します。大文字と小文字を区別します。
match_by = "re"正規表現で比較します。大文字と小文字を区別します。
sort結果を key で並べ替えます。direction は asc(デフォルト)または desc です。

一致する結果がない場合、空の一覧が返され、flavors[0] などの式で Invalid index エラーが発生します。前のセクションのように一覧全体を表示して、フィルターの値を確認してください。

次のステップ​