メインコンテンツまでスキップ

複数の環境向けに構成を整理する

プロジェクトに staging 環境と production 環境の両方がある場合、環境ごとに構成をコピーすると差異が生じやすく、保守も難しくなります。Terraform の module を使うと、構成を一度だけ記述し、サイズを変えてすべての環境で再利用できます。各環境は独自のフォルダーと state を持つため、staging での変更が production に影響することはありません。

前提条件​

  • ✅ 完全な Web アプリケーション基盤を構築する を完了しているか、そこで使用している resource に慣れていること。
  • ✅ 各環境で専用の VPC を使用すること。同じ VPC を共有する場合は、重複しない CIDR 範囲を使用すること。

フォルダー構成​

infra/
├── modules/
│ └── web-stack/ # 共通の module
│ ├── versions.tf
│ ├── variables.tf
│ ├── main.tf
│ └── outputs.tf
└── environments/
├── staging/ # 環境ごとに 1 つのフォルダー、1 つの state
│ └── main.tf
└── production/
└── main.tf
フォルダー内容
modules/web-stack1 つの環境の Subnet、Instance、Security Group です。特定の環境に固有の値は含みません。
environments/<name>その環境の値で module を呼び出します。terraform はこのフォルダーで実行します。

module を記述する​

module が使用する provider です。このブロックがないと、Terraform は誤って provider hashicorp/fptcloud を探し、terraform init の実行時にエラーを報告します。

# modules/web-stack/versions.tf
terraform {
required_providers {
fptcloud = {
source = "fpt-corp/fptcloud"
}
}
}

module の 入力変数 です。

# modules/web-stack/variables.tf
variable "vpc_id" { type = string }
variable "name_prefix" { type = string }
variable "cidr" { type = string }
variable "image_name" { type = string }
variable "storage_policy_id" { type = string }
variable "ssh_public_key" { type = string }
variable "office_cidr" { type = string }
# modules/web-stack/variables.tf
variable "instance_count" {
type = number
default = 1
}

variable "cpu" {
type = number
default = 2
}

variable "memory_mb" {
type = number
default = 4096
}

variable "attach_security_groups" {
type = bool
default = true
}

module の リソース です。flavor は cpu と memory_mb で選択するため、各環境ではサイズを宣言するだけで済みます。

# modules/web-stack/main.tf
data "fptcloud_flavor" "this" {
vpc_id = var.vpc_id

filter {
key = "cpu"
values = [tostring(var.cpu)]
}
filter {
key = "memory_mb"
values = [tostring(var.memory_mb)]
}
}
# modules/web-stack/main.tf
resource "fptcloud_subnet" "this" {
vpc_id = var.vpc_id
name = "${var.name_prefix}-subnet"
type = "NAT_ROUTED"
cidr = var.cidr
gateway_ip = cidrhost(var.cidr, 1)
}
# modules/web-stack/main.tf
resource "fptcloud_instance" "this" {
count = var.instance_count

vpc_id = var.vpc_id
name = format("%s-web-%02d", var.name_prefix, count.index + 1)
image_name = var.image_name
flavor_name = data.fptcloud_flavor.this.flavors[0].name
subnet_id = fptcloud_subnet.this.id
storage_size_gb = 40
storage_policy_id = var.storage_policy_id
ssh_key = var.ssh_public_key
status = "POWERED_ON"
}
# modules/web-stack/main.tf
data "fptcloud_instance" "this" {
count = var.instance_count

vpc_id = var.vpc_id
id = fptcloud_instance.this[count.index].id
}
# modules/web-stack/main.tf
resource "fptcloud_security_group" "this" {
vpc_id = var.vpc_id
name = "${var.name_prefix}-web-sg"
subnet_id = fptcloud_subnet.this.id
type = "ACL"
apply_to = var.attach_security_groups ? data.fptcloud_instance.this[*].private_ip : []
}
# modules/web-stack/main.tf
locals {
rules = {
http = { port = "80", source = "ALL" }
https = { port = "443", source = "ALL" }
ssh = { port = "22", source = var.office_cidr }
}
}
# modules/web-stack/main.tf
resource "fptcloud_security_group_rule" "this" {
for_each = local.rules

vpc_id = var.vpc_id
security_group_id = fptcloud_security_group.this.id
direction = "INGRESS"
action = "ALLOW"
protocol = "TCP"
port_range = each.value.port
sources = [each.value.source]
description = "Allow ${each.key}"
}

module の 出力 です。

# modules/web-stack/outputs.tf
output "subnet_id" {
value = fptcloud_subnet.this.id
}

output "private_ips" {
value = data.fptcloud_instance.this[*].private_ip
}

各環境から module を呼び出す​

staging 環境 では小さな Instance を 1 台使用します。

# environments/staging/main.tf
terraform {
required_providers {
fptcloud = {
source = "fpt-corp/fptcloud"
version = "~> 0.3"
}
}
}

provider "fptcloud" {}

data "fptcloud_vpc" "this" {
name = "example-vpc-staging"
}
# environments/staging/main.tf
data "fptcloud_image" "ubuntu" {
vpc_id = data.fptcloud_vpc.this.id

filter {
key = "name"
values = ["UBUNTU-22.04"]
match_by = "substring"
}
}

data "fptcloud_storage_policy" "ssd" {
vpc_id = data.fptcloud_vpc.this.id

filter {
key = "name"
values = ["Premium-SSD"]
}
}
# environments/staging/main.tf
module "web" {
source = "../../modules/web-stack"

vpc_id = data.fptcloud_vpc.this.id
name_prefix = "shop-staging"
cidr = "10.60.1.0/24"
image_name = data.fptcloud_image.ubuntu.images[0].name
storage_policy_id = data.fptcloud_storage_policy.ssd.storage_policies[0].id
ssh_public_key = file(pathexpand("~/.ssh/id_rsa.pub"))
office_cidr = "203.0.113.0/24"
instance_count = 1
}

output "web_private_ips" {
value = module.web.private_ips
}

production 環境 では同じ module を使用し、値だけを変えます。たとえば、production では Instance を 3 台使用し、各 Instance は 4 vCPU、8 GB RAM です。

module "web" {
source = "../../modules/web-stack"

# ... staging と同じ引数。値を production 用に変更します
name_prefix = "shop-production"
cidr = "10.70.1.0/24"
instance_count = 3
cpu = 4
memory_mb = 8192
}

environments/production/main.tf の残りの部分は staging と同じで、VPC の名前だけを production のものにします。

各環境をデプロイする​

変更する環境のフォルダーで Terraform を実行します。

cd environments/staging
terraform init
terraform plan
terraform apply

各フォルダーは独自の state ファイルを持つため、staging で terraform destroy を実行しても production には影響しません。

ヒント

変更はまず staging に適用して確認してから、production に適用してください。2 つの環境は同じ module を共有しているため、staging で問題なく動作した変更は production でも同様の結果になります。

state を共有の場所に保存する​

デフォルトでは、state はマシン上の terraform.tfstate ファイルに保存されます。複数のメンバーでインフラを管理する場合は、全員が同じ state で作業できるように、ロック(locking)と暗号化に対応した共有 backend に state を保存してください。backend の種類については Terraform の backend ドキュメント を参照してください。

警告

state ファイルを Git に commit しないでください。state には機密情報が含まれる場合があります。また、2 人が同時に 1 つの state ファイルを編集すると、state が破損しやすくなります。

環境を削除する​

完全な Web アプリケーション基盤を構築する と同様に、先に Security Group を外してから削除します。module の変数に値を渡すには、module ブロックに attach_security_groups = var.attach_security_groups を追加し、環境のフォルダーで変数 attach_security_groups を宣言します。

次のステップ​