メインコンテンツまでスキップ

Instance の例

Instance は FPT Cloud 上で動作する仮想サーバーです。このページでは、単一の Instance から複数の物理サーバーに分散した Instance のグループまで、よくあるシナリオ向けの Terraform の例を紹介します。Instance の概念については Instance の概要 を参照してください。

前提条件​

共通設定​

このページの例では、以下の参照ブロックと Subnet を共通で使用します。shared.tf ファイルに保存してください。

# shared.tf
data "fptcloud_vpc" "example" {
name = "example-vpc"
}
# shared.tf
data "fptcloud_image" "ubuntu" {
vpc_id = data.fptcloud_vpc.example.id

filter {
key = "name"
values = ["UBUNTU-22.04"]
match_by = "substring"
}
}
# shared.tf
data "fptcloud_flavor" "small" {
vpc_id = data.fptcloud_vpc.example.id

filter {
key = "cpu"
values = ["2"]
}
filter {
key = "memory_mb"
values = ["4096"]
}
}
# shared.tf
data "fptcloud_storage_policy" "ssd" {
vpc_id = data.fptcloud_vpc.example.id

filter {
key = "name"
values = ["Premium-SSD"]
}
}
# shared.tf
resource "fptcloud_subnet" "app" {
vpc_id = data.fptcloud_vpc.example.id
name = "app-subnet"
type = "NAT_ROUTED"
cidr = "10.10.1.0/24"
gateway_ip = "10.10.1.1"
}

SSH key を使う Linux Instance​

最も一般的な構成で、SSH key でログインする Linux Instance です。ssh_key 引数には public key の内容そのものを指定します。

# instance.tf
resource "fptcloud_instance" "app" {
vpc_id = data.fptcloud_vpc.example.id
name = "app-server-01"
image_name = data.fptcloud_image.ubuntu.images[0].name
flavor_name = data.fptcloud_flavor.small.flavors[0].name
subnet_id = fptcloud_subnet.app.id
storage_size_gb = 40
storage_policy_id = data.fptcloud_storage_policy.ssd.storage_policies[0].id
ssh_key = file(pathexpand("~/.ssh/id_rsa.pub"))
status = "POWERED_ON"
}

FPT Cloud に SSH key を登録する​

fptcloud_ssh_key で public key を登録すると、key が Portal の Compute Engine → SSH Keys に表示され、複数の Instance で再利用できます。

# ssh.tf
resource "fptcloud_ssh_key" "deployer" {
name = "deployer-key"
public_key = file(pathexpand("~/.ssh/id_rsa.pub"))
}

resource "fptcloud_instance" "worker" {
vpc_id = data.fptcloud_vpc.example.id
name = "worker-01"
image_name = data.fptcloud_image.ubuntu.images[0].name
flavor_name = data.fptcloud_flavor.small.flavors[0].name
subnet_id = fptcloud_subnet.app.id
storage_size_gb = 40
storage_policy_id = data.fptcloud_storage_policy.ssd.storage_policies[0].id
ssh_key = fptcloud_ssh_key.deployer.public_key
status = "POWERED_ON"
}

key がすでに Portal に登録されている場合は、名前で key を読み取り、その public_key を使用します。

# ssh.tf
data "fptcloud_ssh_key" "team" {
name = "team-key"
}

その後、Instance に ssh_key = data.fptcloud_ssh_key.team.public_key を設定します。

警告

実行中の Instance の ssh_key を変更すると、Instance が削除されて再作成されます。key を変更する必要がある場合は、Terraform の構成を編集するのではなく、Instance の OS 内で直接更新してください。

パスワードを使う Instance​

パスワードでログインする場合は、ssh_key の代わりに password を使用します。Terraform が画面に表示しないように、sensitive = true を指定した変数でパスワードを渡してください。

# windows.tf
variable "admin_password" {
type = string
sensitive = true
}

data "fptcloud_image" "windows" {
vpc_id = data.fptcloud_vpc.example.id

filter {
key = "name"
values = ["WINSRV-STD2022"]
match_by = "substring"
}
}
# windows.tf
resource "fptcloud_instance" "windows" {
vpc_id = data.fptcloud_vpc.example.id
name = "win-server-01"
image_name = data.fptcloud_image.windows.images[0].name
flavor_name = data.fptcloud_flavor.small.flavors[0].name
subnet_id = fptcloud_subnet.app.id
storage_size_gb = 80
storage_policy_id = data.fptcloud_storage_policy.ssd.storage_policies[0].id
password = var.admin_password
status = "POWERED_ON"
}

コマンドを実行するときに、環境変数でパスワードを渡します。

export TF_VAR_admin_password="YOUR_STRONG_PASSWORD"
terraform apply
警告

各 Instance では ssh_key と password のどちらか一方だけを使用します。パスワードは state に保存されるため、state ファイルは慎重に保護してください。

固定のプライベート IP を持つ Instance​

他のシステムが既知のアドレスで Instance にアクセスする必要がある場合は、private_ip を設定します。アドレスは Subnet の CIDR 範囲内にあり、未使用である必要があります。

# fixed-ip.tf
resource "fptcloud_instance" "db" {
vpc_id = data.fptcloud_vpc.example.id
name = "db-server-01"
image_name = data.fptcloud_image.ubuntu.images[0].name
flavor_name = data.fptcloud_flavor.small.flavors[0].name
subnet_id = fptcloud_subnet.app.id
private_ip = "10.10.1.50"
storage_size_gb = 100
storage_policy_id = data.fptcloud_storage_policy.ssd.storage_policies[0].id
ssh_key = file(pathexpand("~/.ssh/id_rsa.pub"))
status = "POWERED_ON"
}

private_ip は Instance の作成時にのみ使用されます。作成後にこの値を変更しても、Instance の IP は変わりません。

同じ構成の複数の Instance​

同じ構成の Instance を複数作成するには count を使用します。名前には自動的に番号が付きます。

# web.tf
variable "web_count" {
type = number
default = 3
}

resource "fptcloud_instance" "web" {
count = var.web_count

vpc_id = data.fptcloud_vpc.example.id
name = format("web-server-%02d", count.index + 1)
image_name = data.fptcloud_image.ubuntu.images[0].name
flavor_name = data.fptcloud_flavor.small.flavors[0].name
subnet_id = fptcloud_subnet.app.id
storage_size_gb = 40
storage_policy_id = data.fptcloud_storage_policy.ssd.storage_policies[0].id
ssh_key = file(pathexpand("~/.ssh/id_rsa.pub"))
status = "POWERED_ON"
}

この構成では web-server-01、web-server-02、web-server-03 が作成されます。web_count を増やすと、実行中の Instance に影響を与えずに Instance を追加できます。

構成の異なる複数の Instance​

Instance ごとに役割とサイズが異なる場合は、map と for_each を使用します。

# servers.tf
locals {
servers = {
api = { disk_gb = 40 }
worker = { disk_gb = 80 }
report = { disk_gb = 120 }
}
}
# servers.tf
resource "fptcloud_instance" "server" {
for_each = local.servers

vpc_id = data.fptcloud_vpc.example.id
name = "${each.key}-server"
image_name = data.fptcloud_image.ubuntu.images[0].name
flavor_name = data.fptcloud_flavor.small.flavors[0].name
subnet_id = fptcloud_subnet.app.id
storage_size_gb = each.value.disk_gb
storage_policy_id = data.fptcloud_storage_policy.ssd.storage_policies[0].id
ssh_key = file(pathexpand("~/.ssh/id_rsa.pub"))
status = "POWERED_ON"
}
ヒント

for_each を使うと、各 Instance は fptcloud_instance.server["api"] のような安定したアドレスを持ちます。map から要素を 1 つ削除すると、その Instance だけが削除されます。これに対して count では、後ろにある Instance のインデックスがずれる場合があります。

複数の物理サーバーに分散する Instance Group​

Soft Anti Affinity ポリシーを持つ Instance Group は、Instance を異なる物理サーバーに配置することを優先します。これにより、1 台のハードウェア障害でグループ全体が停止することを防げます。Instance Group の概要 によると、1 つのグループには、他のグループに属していない Instance が 2 ~ 10 台必要です。

ポリシーを参照し、上記の web の例の Instance 用にグループを作成します。

# group.tf
data "fptcloud_instance_group_policy" "anti_affinity" {
vpc_id = data.fptcloud_vpc.example.id

filter {
key = "name"
values = ["Soft Anti Affinity"]
}
}

resource "fptcloud_instance_group" "web" {
vpc_id = data.fptcloud_vpc.example.id
name = "web-group"
policy_id = data.fptcloud_instance_group_policy.anti_affinity.instance_group_policies[0].id
vm_ids = fptcloud_instance.web[*].id
}
警告

fptcloud_instance_group のすべての引数は、変更するとグループが再作成されます。vm_ids も例外ではありません。vm_ids の Instance を追加または削除すると、古いグループが削除され、新しいグループが作成されます。

必要なときだけ起動する Instance​

status 引数は Instance の電源状態を決定します。テスト用のマシンなど、作業があるときだけ実行すればよい Instance には POWERED_OFF を設定します。

# test-box.tf
variable "test_box_running" {
type = bool
default = false
}

resource "fptcloud_instance" "test_box" {
vpc_id = data.fptcloud_vpc.example.id
name = "test-box-01"
image_name = data.fptcloud_image.ubuntu.images[0].name
flavor_name = data.fptcloud_flavor.small.flavors[0].name
subnet_id = fptcloud_subnet.app.id
storage_size_gb = 40
storage_policy_id = data.fptcloud_storage_policy.ssd.storage_policies[0].id
ssh_key = file(pathexpand("~/.ssh/id_rsa.pub"))
status = var.test_box_running ? "POWERED_ON" : "POWERED_OFF"
}

terraform apply -var="test_box_running=true" で Instance を起動します。

Instance のプライベート IP を読み取る​

作成直後の Instance は、しばらくの間プライベート IP を報告しない場合があります。Security Group を割り当てるときなどは、data source で Instance を読み直して IP を取得してください。

# ip.tf
data "fptcloud_instance" "app" {
vpc_id = data.fptcloud_vpc.example.id
id = fptcloud_instance.app.id
}

output "app_private_ip" {
value = data.fptcloud_instance.app.private_ip
}

最初の apply の後に app_private_ip が空の場合は、terraform apply を再度実行してください。

よく使う引数​

引数必須変更した場合
vpc_idはいInstance を再作成します。
nameはいその場で名前を変更します。名前に空白は使用できません。
image_nameはいInstance を再作成します。
subnet_idはいInstance を再作成します。
flavor_name設定を推奨その場で resize します。インフラを変更・拡張する を参照してください。
storage_size_gbはいその場で root disk の容量を増やします。減らすことはできません。
storage_policy_idはいその場で root disk を新しい storage policy に移行します。
statusはいその場で Instance を起動または停止します。値は POWERED_ON、POWERED_OFF です。
ssh_key または passwordはい、いずれか一方Instance を再作成します。
private_ipいいえ作成時にのみ使用されます。
tag_idsいいえその場で tag を更新します。tag の例 を参照してください。

すべての引数の一覧は、provider リファレンスドキュメントの fptcloud_instance を参照してください。

注記

root disk は Instance に属し、storage_size_gb と storage_policy_id で管理されます。root disk に対して fptcloud_storage を宣言しないでください。Security Group を割り当てるには、ネットワークの例 のように Security Group の apply_to 引数を使用します。

次のステップ​