メインコンテンツまでスキップ

ネットワークの例

ネットワークは、Instance が受け取るアドレス、トラフィックを受信できる送信元、Internet からアクセスできるかどうかを決定します。このページでは、Subnet、Security Group、Floating IP の Terraform の例と、よくあるエラーを避けるための注意点を紹介します。

前提条件​

共通設定​

# shared.tf
data "fptcloud_vpc" "example" {
name = "example-vpc"
}

data "fptcloud_instance" "app" {
vpc_id = data.fptcloud_vpc.example.id
name = "app-server-01"
}

Subnet​

Subnet は VPC 内の IP アドレス範囲です。Instance は、配置された Subnet からプライベート IP を受け取ります。詳細は Subnet の概要 を参照してください。

アプリケーション用の Subnet​

NAT_ROUTED タイプの Subnet では、Instance が NAT gateway を経由して Internet へ送信方向のアクセスを行えます。パッチのダウンロードや外部サービスの呼び出しが必要な Web サーバーや API サーバーに適しています。

# subnet.tf
resource "fptcloud_subnet" "app" {
vpc_id = data.fptcloud_vpc.example.id
name = "app-subnet"
type = "NAT_ROUTED"
cidr = "10.10.1.0/24"
gateway_ip = "10.10.1.1"
}

データベース用の分離された Subnet​

ISOLATED タイプの Subnet には、Internet へのルーティングがありません。内部の Instance は VPC 内でのみ通信するため、データベースやキャッシュに適しています。

# subnet.tf
resource "fptcloud_subnet" "db" {
vpc_id = data.fptcloud_vpc.example.id
name = "db-subnet"
type = "ISOLATED"
cidr = "10.10.2.0/24"
gateway_ip = "10.10.2.1"
}

静的 IP 範囲と独自の DNS を持つ Subnet​

静的割り当て用にアドレス範囲を確保するには static_ip_pool を使用し、DNS サーバーを指定するには primary_dns_ip と secondary_dns_ip を使用します。

# subnet.tf
resource "fptcloud_subnet" "internal" {
vpc_id = data.fptcloud_vpc.example.id
name = "internal-subnet"
type = "NAT_ROUTED"
cidr = "10.10.3.0/24"
gateway_ip = "10.10.3.1"
static_ip_pool = "10.10.3.100-10.10.3.200"
primary_dns_ip = "10.10.0.10"
secondary_dns_ip = "10.10.0.11"
}

static_ip_pool は空白を含めずに <start_address>-<end_address> の形式で記述し、cidr の範囲内に収める必要があります。

1 つのアドレス範囲から複数の Subnet を作成する​

cidrsubnet() 関数は大きな範囲を /24 の範囲に分割するため、アドレスを手動で計算する必要がありません。

# subnets.tf
locals {
base_cidr = "10.20.0.0/16"
tiers = { web = 1, app = 2, db = 3 }
}

resource "fptcloud_subnet" "tier" {
for_each = local.tiers

vpc_id = data.fptcloud_vpc.example.id
name = "${each.key}-subnet"
type = each.key == "db" ? "ISOLATED" : "NAT_ROUTED"
cidr = cidrsubnet(local.base_cidr, 8, each.value)
gateway_ip = cidrhost(cidrsubnet(local.base_cidr, 8, each.value), 1)
}

この構成では、web-subnet(10.20.1.0/24)、app-subnet(10.20.2.0/24)、db-subnet(10.20.3.0/24)が作成されます。

警告

Subnet の CIDR 範囲は VPC 内の他の Subnet と重複できず、gateway_ip は CIDR 範囲内にある必要があります。name、type、cidr、gateway_ip、static_ip_pool のいずれかを変更すると Subnet が再作成され、それに伴いその Subnet 内のすべての Instance も再作成されます。

Security Group​

Security Group は、Instance の受信および送信トラフィックを制御する仮想ファイアウォールです。どの rule にも一致しないトラフィックは拒否されます。詳細は Security Group の概要 を参照してください。

Security Group を作成する際は type 引数が必須です。type = "ACL" を指定してください。

Web サーバー用の Security Group​

以下の例では、HTTP と HTTPS をすべての送信元から許可し、SSH はオフィスのネットワークからのみ許可します。Security Group は apply_to 引数で Instance に割り当てます。この引数には、保護する Instance のプライベート IP のリストを指定します。

# security.tf
resource "fptcloud_security_group" "web" {
vpc_id = data.fptcloud_vpc.example.id
name = "web-sg"
subnet_id = fptcloud_subnet.app.id
type = "ACL"
apply_to = [data.fptcloud_instance.app.private_ip]
}
# security.tf
locals {
web_rules = {
http = { port = "80", source = "ALL" }
https = { port = "443", source = "ALL" }
ssh = { port = "22", source = "203.0.113.0/24" } # オフィスのネットワーク
}
}
# security.tf
resource "fptcloud_security_group_rule" "web" {
for_each = local.web_rules

vpc_id = data.fptcloud_vpc.example.id
security_group_id = fptcloud_security_group.web.id
direction = "INGRESS"
action = "ALLOW"
protocol = "TCP"
port_range = each.value.port
sources = [each.value.source]
description = "Allow ${each.key}"
}

map と for_each を使うと、他の rule に影響を与えずに rule を追加または削除できます。

データベース用の Security Group​

PostgreSQL(ポート 5432)への接続をアプリケーションサーバーからのみ許可します。送信元にはアプリケーション Subnet の CIDR 範囲を指定します。

# security.tf
data "fptcloud_instance" "db" {
vpc_id = data.fptcloud_vpc.example.id
name = "db-server-01"
}

resource "fptcloud_security_group" "db" {
vpc_id = data.fptcloud_vpc.example.id
name = "db-sg"
subnet_id = fptcloud_subnet.db.id
type = "ACL"
apply_to = [data.fptcloud_instance.db.private_ip]
}
# security.tf
resource "fptcloud_security_group_rule" "postgres" {
vpc_id = data.fptcloud_vpc.example.id
security_group_id = fptcloud_security_group.db.id
direction = "INGRESS"
action = "ALLOW"
protocol = "TCP"
port_range = "5432"
sources = [fptcloud_subnet.app.cidr]
description = "PostgreSQL from the app subnet"
}

複数の Instance に 1 つの Security Group を適用する​

保護するすべての Instance のプライベート IP を apply_to に指定します。以下の例では、名前が web-server- で始まるすべての Instance の IP を取得します。このリストは terraform apply を実行するたびに読み直されるため、新しい Instance は次回の apply で Security Group に追加されます。

# security.tf
data "fptcloud_instances" "all" {
vpc_id = data.fptcloud_vpc.example.id
}

locals {
web_ips = [
for vm in data.fptcloud_instances.all.instances : vm.private_ip
if startswith(vm.name, "web-server-")
]
}

その後、Security Group に apply_to = local.web_ips を設定します。

rule の値​

引数値
direction受信トラフィックには INGRESS、送信トラフィックには EGRESS。
action常に ALLOW を指定します。Security Group は拒否 rule をサポートしておらず、どの rule にも一致しないトラフィックはもともと拒否されます。
protocolTCP、UDP、ICMP、または ALL。
port_range単一のポート("22")、ポート範囲("8000-8100")、または "ALL"。protocol = "ALL" の場合は "ALL" が必須です。
sourcesIPv4 の CIDR 範囲、単一の IPv4 アドレス、または "ALL"。EGRESS の rule では宛先アドレスを表します。

各 rule には、送信元を 1 つと、ポートまたはポート範囲を 1 つだけ指定してください。1 つのポートを複数の送信元に開放する場合や、複数のポートを 1 つの送信元に開放する場合は、上記の Web サーバーの例のように for_each を使って組み合わせごとに rule を作成します。sources に複数の値を指定すると、FPT Cloud はそれらを別々の rule に分割するため、terraform destroy ですべてを削除できない場合があります。

警告

rule はその場で変更できません。description を含め、rule のいずれかの引数を変更すると、古い rule が削除されてから新しい rule が作成されます。2 つの手順の間のわずかな時間、その rule のトラフィックがブロックされる場合があります。

apply_to で Security Group を割り当てる​

Security Group は Instance の security_group_ids 引数ではなく、Security Group の apply_to で割り当ててください。security_group_ids は Instance の作成時にのみ有効です。また、FPT Cloud は apply_to で割り当てた Security Group も報告するため、plan が常に変更ありと表示されます。

作成直後の Instance は、しばらくの間プライベート IP を報告しない場合があります。上記の例のように、data source fptcloud_instance で IP を読み取ってください。最初の apply の後に apply_to が空の場合は、terraform apply を再度実行してください。

Security Group の削除​

FPT Cloud では、Security Group はどのリソースにも割り当てられていない場合にのみ削除できます。Security Group をその Instance と一緒に削除する前に、次の手順を実行します。

  1. Security Group に apply_to = [] を設定します。
  2. terraform apply を実行します。
  3. terraform destroy を実行します。

完全な Web アプリケーション基盤を構築する では、変数を使ってこの手順をより簡潔に行う方法を紹介しています。

Floating IP​

Floating IP は、独立して確保してから Instance に割り当てるパブリック IP アドレスです。IP は Instance に固定されないため、DNS の設定を変更せずに IP を別の Instance に移動できます。詳細は Floating IP の概要 を参照してください。

Floating IP の確保と割り当て​

# public-ip.tf
resource "fptcloud_floating_ip" "app" {
vpc_id = data.fptcloud_vpc.example.id
}

resource "fptcloud_floating_ip_association" "app" {
vpc_id = data.fptcloud_vpc.example.id
floating_ip_id = fptcloud_floating_ip.app.id
instance_id = data.fptcloud_instance.app.id
}

output "public_ip" {
value = fptcloud_floating_ip.app.ip_address
}

fptcloud_floating_ip は IP アドレスを保持し、fptcloud_floating_ip_association はそのアドレスを Instance に割り当てます。2 つの resource に分けることで、IP を別の Instance に移動しても IP アドレスは変わりません。

Floating IP を別の Instance に移動する​

既存の fptcloud_floating_ip_association の instance_id を変更し、terraform apply を実行します。Terraform は IP を古い Instance から外して新しい Instance に割り当てます。IP アドレスは変わりません。

data "fptcloud_instance" "standby" {
vpc_id = data.fptcloud_vpc.example.id
name = "app-server-02"
}

resource "fptcloud_floating_ip_association" "app" {
vpc_id = data.fptcloud_vpc.example.id
floating_ip_id = fptcloud_floating_ip.app.id
instance_id = data.fptcloud_instance.standby.id # 以前は data.fptcloud_instance.app.id
}

1 つの Floating IP に対して fptcloud_floating_ip_association は 1 つだけにしてください。IP を移動するときは、新しい resource を追加するのではなく、既存の resource を編集します。

ヒント

Floating IP は、Instance の public_ip 引数ではなく fptcloud_floating_ip_association で割り当ててください。public_ip は Instance の作成時にのみ有効なため、後から IP を移動したり外したりするためには使用できません。

次のステップ​