Tra cứu thông tin bằng data source
Trang này hướng dẫn cách tra cứu thông tin bằng data source, nền tảng của mọi ví dụ trong mục Ví dụ theo tài nguyên. Tra cứu bằng data source thay vì sao chép ID thủ công giúp cấu hình của bạn chạy được ở VPC khác mà không phải sửa.
Điều kiện tiên quyết
- ✅ Đã hoàn thành Cài đặt và cấu hình.
Tra cứu VPC
Hầu hết tài nguyên cần vpc_id. Tra cứu VPC theo tên:
data "fptcloud_vpc" "example" {
name = "example-vpc"
}
Dùng data.fptcloud_vpc.example.id ở mọi nơi cần vpc_id. Data source này tìm VPC trong tenant khai báo ở provider. Nếu không tìm thấy, terraform plan dừng với lỗi.
Tra cứu flavor
Flavor quyết định số vCPU và dung lượng RAM của Instance.
Chọn theo cấu hình phần cứng. Cách này chạy được ở mọi VPC có flavor phù hợp:
data "fptcloud_flavor" "medium" {
vpc_id = data.fptcloud_vpc.example.id
filter {
key = "cpu"
values = ["4"]
}
filter {
key = "memory_mb"
values = ["8192"]
}
filter {
key = "type"
values = ["VM_SIZE"]
}
}
Chọn theo tên khi bạn đã biết chính xác tên flavor trong VPC:
data "fptcloud_flavor" "by_name" {
vpc_id = data.fptcloud_vpc.example.id
filter {
key = "name"
values = ["Medium-4"] # Thay bằng tên flavor có trong VPC của bạn
}
}
Dùng data.fptcloud_flavor.medium.flavors[0].name cho tham số flavor_name của Instance.
Tra cứu image
Tìm theo một phần tên, bỏ qua image GPU:
data "fptcloud_image" "ubuntu" {
vpc_id = data.fptcloud_vpc.example.id
filter {
key = "name"
values = ["UBUNTU-22.04"]
match_by = "substring"
}
filter {
key = "is_gpu"
values = ["false"]
}
}
Tìm bằng biểu thức chính quy và sắp xếp để luôn chọn cùng một image:
data "fptcloud_image" "rocky" {
vpc_id = data.fptcloud_vpc.example.id
filter {
key = "name"
values = ["^ROCKYLINUX-9"]
match_by = "re"
}
sort {
key = "name"
direction = "desc"
}
}
Dùng data.fptcloud_image.ubuntu.images[0].name cho tham số image_name của Instance.
Đổi image_name của một Instance đang chạy sẽ xóa và tạo lại Instance. Nếu bộ lọc image của bạn có thể trả về image mới hơn theo thời gian, hãy cố định tên image cho Instance quan trọng.
Tra cứu storage policy
Storage policy là mức hiệu năng của disk:
data "fptcloud_storage_policy" "ssd" {
vpc_id = data.fptcloud_vpc.example.id
filter {
key = "name"
values = ["Premium-SSD"] # Thay bằng tên storage policy có trong VPC của bạn
}
}
Dùng data.fptcloud_storage_policy.ssd.storage_policies[0].id cho tham số storage_policy_id.
Tra cứu tài nguyên có sẵn
Dùng data source để tham chiếu tài nguyên đã tạo trên Portal mà không đưa chúng vào Terraform quản lý.
data "fptcloud_subnet" "shared" {
vpc_id = data.fptcloud_vpc.example.id
filter {
key = "name"
values = ["shared-subnet"]
}
}
data "fptcloud_instance" "jump_host" {
vpc_id = data.fptcloud_vpc.example.id
name = "jump-host-01"
}
data.fptcloud_subnet.shared.subnets[0].idtrả về ID của Subnet.data.fptcloud_instance.jump_host.private_iptrả về IP private của Instance.
Liệt kê để xem các giá trị có sẵn
Bỏ khối filter để lấy toàn bộ danh sách, rồi in ra bằng output:
data "fptcloud_flavor" "all" {
vpc_id = data.fptcloud_vpc.example.id
}
output "flavors" {
value = [for f in data.fptcloud_flavor.all.flavors : "${f.name}: ${f.cpu} vCPU, ${f.memory_mb} MB"]
}
Chạy terraform apply để xem danh sách. Data source chỉ đọc dữ liệu, không tạo tài nguyên nào.
Quy tắc của bộ lọc
Các data source fptcloud_flavor, fptcloud_image, fptcloud_storage_policy, fptcloud_subnet và fptcloud_instance_group_policy dùng chung khối filter và sort:
| Thành phần | Cách hoạt động |
|---|---|
Nhiều khối filter | Kết quả phải khớp tất cả các khối. |
Nhiều giá trị trong values | Kết quả chỉ cần khớp một giá trị. |
match_by = "exact" | Mặc định. So khớp toàn bộ chuỗi, không phân biệt chữ hoa và chữ thường. |
match_by = "substring" | Chuỗi chứa giá trị cần tìm. Phân biệt chữ hoa và chữ thường. |
match_by = "re" | So khớp bằng biểu thức chính quy. Phân biệt chữ hoa và chữ thường. |
sort | Sắp xếp kết quả theo key, direction là asc (mặc định) hoặc desc. |
Khi không có kết quả nào khớp, danh sách trả về rỗng và biểu thức như flavors[0] báo lỗi Invalid index. Kiểm tra lại giá trị lọc bằng cách liệt kê toàn bộ danh sách như ở mục trước.