Thay đổi và mở rộng hạ tầng
Nhu cầu của ứng dụng thay đổi theo thời gian. Trang này hướng dẫn cách điều chỉnh tài nguyên đang chạy bằng Terraform một cách an toàn: thay đổi tại chỗ, không tạo lại tài nguyên và không mất dữ liệu.
Điều kiện tiên quyết
- ✅ Hạ tầng đang được Terraform quản lý, ví dụ theo Dựng hạ tầng ứng dụng web hoàn chỉnh.
Đọc plan trước mọi thay đổi
Luôn chạy terraform plan và đọc kết quả trước khi apply:
| Plan hiển thị | Ý nghĩa |
|---|---|
~ update in-place | Tài nguyên được cập nhật và giữ nguyên dữ liệu. |
-/+ destroy and then create replacement | Tài nguyên bị xóa rồi tạo lại. Với Instance, dữ liệu trên root disk bị mất. |
# forces replacement | Đánh dấu tham số gây ra việc tạo lại. |
Mọi thay đổi trên trang này đều là thay đổi tại chỗ.
Lưu plan rồi apply đúng plan đó, để những gì được áp dụng khớp chính xác với những gì bạn đã đọc:
terraform plan -out=tfplan
terraform apply tfplan
Đổi cấu hình vCPU và RAM
Đổi flavor để tăng hoặc giảm vCPU và RAM. Nếu bạn chọn flavor bằng bộ lọc, chỉ cần sửa giá trị lọc:
data "fptcloud_flavor" "app" {
vpc_id = data.fptcloud_vpc.example.id
filter {
key = "cpu"
values = ["4"] # trước đây là 2
}
filter {
key = "memory_mb"
values = ["8192"] # trước đây là 4096
}
}
Plan hiển thị ~ flavor_name cho Instance dùng flavor này. Sau khi apply, Terraform chờ tới khi resize hoàn tất. Toàn bộ dữ liệu và cấu hình trên Instance được giữ nguyên.
Theo hướng dẫn Resize, trước khi resize:
- Instance phải ở trạng thái Running hoặc Stopped.
- Instance dùng storage NVMe không hỗ trợ resize.
- Instance đang gắn GPU phải được gỡ GPU trước.
Tăng dung lượng root disk
Tăng storage_size_gb của Instance:
resource "fptcloud_instance" "app" {
# ...
storage_size_gb = 80 # trước đây là 40
}
Root disk chỉ tăng được. Nếu bạn đặt giá trị nhỏ hơn, terraform plan dừng với lỗi trước khi thay đổi bất cứ điều gì.
Sau khi apply, bạn cần vào hệ điều hành của Instance để mở rộng phân vùng tương ứng, theo Quản lý Storage Disk của Instance.
Để chuyển root disk sang mức hiệu năng khác, đổi storage_policy_id của Instance. Thay đổi này cũng được thực hiện tại chỗ.
Tăng dung lượng disk dữ liệu
Tăng size_gb của fptcloud_storage:
resource "fptcloud_storage" "app_data" {
# ...
size_gb = 200 # trước đây là 100
}
Disk được mở rộng tại chỗ, dữ liệu được giữ nguyên. Sau đó, vào hệ điều hành của Instance để mở rộng phân vùng tương ứng.
Dung lượng disk chỉ tăng được, không giảm được. Provider không chặn giá trị nhỏ hơn cho size_gb ở bước terraform plan, vì vậy hãy kiểm tra kỹ trước khi apply.
Bật và tắt Instance
Tham số status quyết định trạng thái nguồn. Một cách dùng phổ biến là tắt Instance dùng cho phát triển ngoài giờ làm việc:
variable "dev_running" {
type = bool
default = true
}
resource "fptcloud_instance" "dev" {
# ...
status = var.dev_running ? "POWERED_ON" : "POWERED_OFF"
}
terraform apply -var="dev_running=false" # cuối ngày
terraform apply -var="dev_running=true" # đầu ngày
Nếu đồng nghiệp cũng bật tắt Instance trên Portal và bạn không muốn Terraform ghi đè, yêu cầu Terraform bỏ qua trạng thái nguồn:
resource "fptcloud_instance" "dev" {
# ...
status = "POWERED_ON"
lifecycle {
ignore_changes = [status]
}
}
Thêm Instance
Khi Instance được tạo bằng count, tăng số lượng để thêm Instance:
variable "web_count" {
type = number
default = 3 # trước đây là 2
}
Terraform tạo thêm Instance mới, các Instance đang chạy không bị ảnh hưởng. Nếu Security Group dùng apply_to lấy IP từ danh sách Instance như trong Dựng hạ tầng ứng dụng web hoàn chỉnh, IP của Instance mới được thêm vào Security Group trong cùng lần apply.
Giảm count sẽ xóa các Instance có chỉ số lớn nhất. Đọc kỹ plan để biết chính xác Instance nào bị xóa. Nếu cần xóa một Instance cụ thể ở giữa danh sách, dùng for_each thay cho count.
Chủ động tạo lại một tài nguyên
Khi một Instance gặp sự cố và bạn muốn tạo lại đúng Instance đó từ cấu hình, dùng -replace:
terraform apply -replace="fptcloud_instance.web[1]"
Terraform chỉ tạo lại tài nguyên được chỉ định, các tài nguyên khác giữ nguyên.
Bảo vệ tài nguyên quan trọng
Thêm prevent_destroy cho tài nguyên mà việc xóa nhầm gây thiệt hại lớn, ví dụ máy chủ cơ sở dữ liệu. Terraform sẽ từ chối mọi plan xóa tài nguyên này, kể cả việc tạo lại do đổi image_name, subnet_id hoặc ssh_key:
resource "fptcloud_instance" "db" {
# ...
lifecycle {
prevent_destroy = true
}
}
Để xóa tài nguyên này một cách có chủ đích, gỡ khối lifecycle trước.