Dựng hạ tầng ứng dụng web hoàn chỉnh
Bài hướng dẫn này dựng trọn hạ tầng cho một ứng dụng web hai lớp — lớp web và lớp cơ sở dữ liệu — chỉ bằng một lệnh terraform apply. Bạn có thể dùng cấu hình này làm điểm khởi đầu cho dự án thật: mọi giá trị riêng của môi trường đều nằm trong biến, nên bạn chỉ cần sửa một file để dựng môi trường mới.
Kiến trúc
Internet
│
Floating IP │ Floating IP
┌──────────┴──────────┐
┌────────────────┼─────────────────────┼──────────── VPC ─┐
│ shop-staging-web-subnet (NAT_ROUTED, 10.50.1.0/24) │
│ shop-staging-web-sg (ACL): 80, 443, 22 từ văn phòng │
│ ┌──────────┴─────────┐ ┌─────────┴──────────┐ │
│ │ shop-staging-web-01│ │ shop-staging-web-02│ │
│ └──────────┬─────────┘ └─────────┬──────────┘ │
│ └──────────┬──────────┘ │
│ │ 5432, 22 │
│ shop-staging-db-subnet (ISOLATED, 10.50.2.0/24) │
│ shop-staging-db-sg (ACL): 5432, 22 từ web subnet │
│ ┌──────────┴──────────┐ │
│ │ shop-staging-db-01 │── shop-staging- │
│ │ (10.50.2.10) │ db-data 100 GB │
│ └─────────────────────┘ │
└──────────────────────────────────────────────────────────┘
| Thành phần | Mục đích |
|---|---|
| Web subnet | Subnet cho máy chủ web, truy cập Internet chiều đi qua NAT gateway. |
| Database subnet | Subnet cô lập cho cơ sở dữ liệu, không có định tuyến ra Internet. |
| 2 Instance web | Chạy ứng dụng web, mỗi Instance có một Floating IP. |
| 1 Instance cơ sở dữ liệu | Chạy cơ sở dữ liệu, dữ liệu nằm trên disk riêng 100 GB. |
| Web Security Group | Cho phép HTTP và HTTPS từ Internet, SSH chỉ từ mạng văn phòng. |
| Database Security Group | Chỉ cho phép máy chủ web kết nối tới cơ sở dữ liệu và SSH. |
| Tag | Gắn environment và project cho mọi tài nguyên để theo dõi chi phí. |
Điều kiện tiên quyết
- ✅ Đã hoàn thành Cài đặt và cấu hình.
- ✅ VPC còn quota cho 2 Subnet, 3 Instance, 1 disk, 2 Floating IP và 2 Security Group.
- ✅ Có cặp SSH key RSA trên máy, ví dụ
~/.ssh/id_rsa.pub. - ✅ Biết dải địa chỉ public của mạng văn phòng, để chỉ cho phép SSH từ đó.
Cấu trúc thư mục
Tạo thư mục shop-infra với các file sau. Tách theo chức năng giúp bạn dễ tìm và dễ review từng phần:
shop-infra/
├── versions.tf # phiên bản Terraform và provider
├── variables.tf # khai báo biến
├── terraform.tfvars # giá trị biến của môi trường
├── data.tf # tra cứu VPC, image, flavor, storage policy
├── tags.tf # tag dùng chung
├── network.tf # Subnet
├── compute.tf # SSH key và Instance
├── storage.tf # disk dữ liệu
├── security.tf # Security Group và rule
├── public-ip.tf # Floating IP
└── outputs.tf # thông tin in ra sau khi apply
Khai báo phiên bản và biến
# versions.tf
terraform {
required_version = ">= 1.5"
required_providers {
fptcloud = {
source = "fpt-corp/fptcloud"
version = "~> 0.3"
}
}
}
provider "fptcloud" {
timeout = 30
}
timeout = 30 cho Terraform chờ tối đa 30 phút mỗi thao tác, phù hợp khi tạo nhiều Instance cùng lúc.
# variables.tf
variable "vpc_name" {
description = "Tên VPC để triển khai."
type = string
}
variable "environment" {
description = "Tên môi trường, ví dụ staging hoặc production."
type = string
}
variable "project" {
description = "Tên dự án, dùng làm tiền tố tên tài nguyên."
type = string
}
# variables.tf
variable "office_cidr" {
description = "Dải IP public của văn phòng, được phép SSH vào máy chủ web."
type = string
}
variable "ssh_public_key_path" {
description = "Đường dẫn tới SSH public key."
type = string
default = "~/.ssh/id_rsa.pub"
}
variable "web_count" {
description = "Số Instance web."
type = number
default = 2
}
# variables.tf
variable "attach_security_groups" {
description = "Đặt false trước khi destroy để gỡ Security Group khỏi Instance."
type = bool
default = true
}
Giá trị của môi trường nằm trong terraform.tfvars. Thay các giá trị dưới đây bằng thông tin của bạn:
# terraform.tfvars
vpc_name = "example-vpc"
environment = "staging"
project = "shop"
office_cidr = "203.0.113.0/24"
web_count = 2
Tra cứu thông tin
Flavor được chọn theo cấu hình phần cứng, nên cấu hình chạy được ở VPC khác mà không cần sửa:
# data.tf
data "fptcloud_vpc" "this" {
name = var.vpc_name
}
# data.tf
data "fptcloud_image" "ubuntu" {
vpc_id = data.fptcloud_vpc.this.id
filter {
key = "name"
values = ["UBUNTU-22.04"] # Thay bằng image có trong VPC của bạn
match_by = "substring"
}
}
# data.tf
data "fptcloud_flavor" "web" {
vpc_id = data.fptcloud_vpc.this.id
filter {
key = "cpu"
values = ["2"]
}
filter {
key = "memory_mb"
values = ["4096"]
}
}
# data.tf
data "fptcloud_flavor" "db" {
vpc_id = data.fptcloud_vpc.this.id
filter {
key = "cpu"
values = ["4"]
}
filter {
key = "memory_mb"
values = ["8192"]
}
}
# data.tf
data "fptcloud_storage_policy" "ssd" {
vpc_id = data.fptcloud_vpc.this.id
filter {
key = "name"
values = ["Premium-SSD"] # Thay bằng storage policy có trong VPC của bạn
}
}
Tag và tiền tố tên
# tags.tf
resource "fptcloud_tagging" "environment" {
key = "environment"
value = var.environment
scope_type = "ORG"
}
resource "fptcloud_tagging" "project" {
key = "project"
value = var.project
scope_type = "ORG"
}
locals {
name_prefix = "${var.project}-${var.environment}"
tag_ids = [fptcloud_tagging.environment.id, fptcloud_tagging.project.id]
image_name = data.fptcloud_image.ubuntu.images[0].name
policy_id = data.fptcloud_storage_policy.ssd.storage_policies[0].id
}
Nếu tổ chức của bạn đã có sẵn tag environment và project, đọc các tag đó bằng data source fptcloud_tagging thay vì tạo mới. Xem Ví dụ tag.
Mạng
# network.tf
resource "fptcloud_subnet" "web" {
vpc_id = data.fptcloud_vpc.this.id
name = "${local.name_prefix}-web-subnet"
type = "NAT_ROUTED"
cidr = "10.50.1.0/24"
gateway_ip = "10.50.1.1"
tag_ids = local.tag_ids
}
resource "fptcloud_subnet" "db" {
vpc_id = data.fptcloud_vpc.this.id
name = "${local.name_prefix}-db-subnet"
type = "ISOLATED"
cidr = "10.50.2.0/24"
gateway_ip = "10.50.2.1"
tag_ids = local.tag_ids
}
Chọn hai dải CIDR không trùng với Subnet đang có trong VPC.
Instance
# compute.tf
resource "fptcloud_ssh_key" "deployer" {
name = "${local.name_prefix}-deployer"
public_key = file(pathexpand(var.ssh_public_key_path))
}
resource "fptcloud_instance" "web" {
count = var.web_count
vpc_id = data.fptcloud_vpc.this.id
name = format("%s-web-%02d", local.name_prefix, count.index + 1)
image_name = local.image_name
flavor_name = data.fptcloud_flavor.web.flavors[0].name
subnet_id = fptcloud_subnet.web.id
storage_size_gb = 40
storage_policy_id = local.policy_id
ssh_key = fptcloud_ssh_key.deployer.public_key
status = "POWERED_ON"
tag_ids = local.tag_ids
}
# compute.tf
resource "fptcloud_instance" "db" {
vpc_id = data.fptcloud_vpc.this.id
name = "${local.name_prefix}-db-01"
image_name = local.image_name
flavor_name = data.fptcloud_flavor.db.flavors[0].name
subnet_id = fptcloud_subnet.db.id
private_ip = "10.50.2.10"
storage_size_gb = 40
storage_policy_id = local.policy_id
ssh_key = fptcloud_ssh_key.deployer.public_key
status = "POWERED_ON"
tag_ids = local.tag_ids
}
Instance cơ sở dữ liệu có IP cố định 10.50.2.10, để cấu hình ứng dụng trên máy chủ web trỏ tới một địa chỉ không đổi.
Disk dữ liệu
# storage.tf
resource "fptcloud_storage" "db_data" {
vpc_id = data.fptcloud_vpc.this.id
name = "${local.name_prefix}-db-data"
type = "EXTERNAL"
size_gb = 100
storage_policy_id = local.policy_id
instance_id = fptcloud_instance.db.id
tag_ids = local.tag_ids
}
Security Group
IP private của Instance được đọc qua data source fptcloud_instance, vì Instance vừa tạo có thể chưa báo IP ngay:
# security.tf
data "fptcloud_instance" "web" {
count = var.web_count
vpc_id = data.fptcloud_vpc.this.id
id = fptcloud_instance.web[count.index].id
}
data "fptcloud_instance" "db" {
vpc_id = data.fptcloud_vpc.this.id
id = fptcloud_instance.db.id
}
# security.tf
resource "fptcloud_security_group" "web" {
vpc_id = data.fptcloud_vpc.this.id
name = "${local.name_prefix}-web-sg"
subnet_id = fptcloud_subnet.web.id
type = "ACL"
apply_to = var.attach_security_groups ? data.fptcloud_instance.web[*].private_ip : []
tag_ids = local.tag_ids
}
resource "fptcloud_security_group" "db" {
vpc_id = data.fptcloud_vpc.this.id
name = "${local.name_prefix}-db-sg"
subnet_id = fptcloud_subnet.db.id
type = "ACL"
apply_to = var.attach_security_groups ? [data.fptcloud_instance.db.private_ip] : []
tag_ids = local.tag_ids
}
# security.tf
locals {
web_rules = {
http = { port = "80", source = "ALL" }
https = { port = "443", source = "ALL" }
ssh = { port = "22", source = var.office_cidr }
}
db_rules = {
postgres = "5432"
ssh = "22"
}
}
# security.tf
resource "fptcloud_security_group_rule" "web" {
for_each = local.web_rules
vpc_id = data.fptcloud_vpc.this.id
security_group_id = fptcloud_security_group.web.id
direction = "INGRESS"
action = "ALLOW"
protocol = "TCP"
port_range = each.value.port
sources = [each.value.source]
description = "Allow ${each.key}"
}
# security.tf
resource "fptcloud_security_group_rule" "db" {
for_each = local.db_rules
vpc_id = data.fptcloud_vpc.this.id
security_group_id = fptcloud_security_group.db.id
direction = "INGRESS"
action = "ALLOW"
protocol = "TCP"
port_range = each.value
sources = [fptcloud_subnet.web.cidr]
description = "Allow ${each.key} from the web subnet"
}
Biến attach_security_groups giúp bạn gỡ Security Group khỏi Instance trước khi xóa hạ tầng, xem Dọn dẹp.
Floating IP
# public-ip.tf
resource "fptcloud_floating_ip" "web" {
count = var.web_count
vpc_id = data.fptcloud_vpc.this.id
tag_ids = local.tag_ids
}
resource "fptcloud_floating_ip_association" "web" {
count = var.web_count
vpc_id = data.fptcloud_vpc.this.id
floating_ip_id = fptcloud_floating_ip.web[count.index].id
instance_id = fptcloud_instance.web[count.index].id
}
Thông tin đầu ra
# outputs.tf
output "web_public_ips" {
description = "Địa chỉ public của các máy chủ web."
value = fptcloud_floating_ip.web[*].ip_address
}
output "web_private_ips" {
description = "Địa chỉ private của các máy chủ web."
value = data.fptcloud_instance.web[*].private_ip
}
output "db_private_ip" {
description = "Địa chỉ private của máy chủ cơ sở dữ liệu."
value = data.fptcloud_instance.db.private_ip
}
Triển khai
-
Mở terminal trong thư mục
shop-infravà khai báo thông tin kết nối như trong Cài đặt và cấu hình. -
Tải provider:
terraform init -
Kiểm tra cú pháp cấu hình:
terraform validate -
Xem trước và lưu kế hoạch:
terraform plan -out=tfplanVới
web_count = 2, plan hiển thịPlan: 20 to add, 0 to change, 0 to destroy. -
Áp dụng đúng kế hoạch đã xem:
terraform apply tfplan
Terraform tạo tài nguyên theo thứ tự phụ thuộc: tag và Subnet trước, rồi Instance, disk, Security Group và Floating IP. Quá trình thường mất 10 tới 20 phút. Khi hoàn tất, Terraform in ra web_public_ips, web_private_ips và db_private_ip.
Nếu web_private_ips hoặc db_private_ip rỗng sau lần apply đầu tiên, chạy lại terraform apply. Lần chạy thứ hai đọc được IP và gắn Security Group cho Instance.
Kiểm tra kết quả
-
Mở FPT Cloud Portal và kiểm tra:
- Hai Subnet, ba Instance ở trạng thái Running, disk
shop-staging-db-datagắn vàoshop-staging-db-01. - Hai Security Group áp dụng cho đúng Instance.
- Hai Floating IP gán cho hai máy chủ web.
- Hai Subnet, ba Instance ở trạng thái Running, disk
-
Đăng nhập máy chủ web từ mạng văn phòng qua Floating IP, bằng user mặc định của image:
ssh -i ~/.ssh/id_rsa <user>@<web_public_ip> -
Từ máy chủ web, kết nối tới máy chủ cơ sở dữ liệu qua IP private
10.50.2.10.
Disk dữ liệu là disk trống. Trước khi cài cơ sở dữ liệu, định dạng disk theo Xử lý sự cố Storage Disks.
Thay đổi hạ tầng sau khi triển khai
| Bạn muốn | Sửa | Kết quả |
|---|---|---|
| Thêm máy chủ web | web_count = 3 trong terraform.tfvars | Thêm Instance và Floating IP, IP mới được thêm vào web Security Group. Instance cũ giữ nguyên. |
| Tăng dung lượng disk dữ liệu | size_gb = 200 trong storage.tf | Disk được mở rộng tại chỗ. |
| Nâng cấu hình cơ sở dữ liệu | Bộ lọc của data.fptcloud_flavor.db | Instance được resize tại chỗ. |
| Mở thêm cổng cho web | Thêm phần tử vào local.web_rules | Chỉ tạo rule mới, rule cũ giữ nguyên. |
Luôn chạy terraform plan và đọc kỹ kết quả trước khi apply. Xem thêm Thay đổi và mở rộng hạ tầng.
Dọn dẹp
FPT Cloud chỉ xóa được Security Group khi nó không còn gắn vào Instance nào. Vì vậy, gỡ Security Group trước rồi mới xóa hạ tầng:
-
Gỡ Security Group khỏi các Instance:
terraform apply -var="attach_security_groups=false" -
Xóa toàn bộ hạ tầng:
terraform destroy -var="attach_security_groups=false" -
Nhập
yesđể xác nhận.
terraform destroy xóa vĩnh viễn mọi Instance, disk và dữ liệu trên đó. Sao lưu dữ liệu cần giữ trước khi chạy lệnh. Hành động không thể hoàn tác.
Mở rộng cấu hình
- Phân bố máy chủ web trên nhiều máy chủ vật lý: đặt các Instance web vào Instance Group với chính sách Soft Anti Affinity, xem Ví dụ Instance.
- Chụp Snapshot trước khi nâng cấp: xem Ví dụ storage.
- Dựng nhiều môi trường từ cùng cấu hình: xem Tổ chức cấu hình cho nhiều môi trường.