Ví dụ network
Mạng quyết định Instance của bạn nhận địa chỉ nào, được phép nhận lưu lượng từ đâu và có truy cập được từ Internet hay không. Trang này đưa ra các ví dụ Terraform cho Subnet, Security Group và Floating IP, kèm các lưu ý giúp bạn tránh lỗi thường gặp.
Điều kiện tiên quyết
- ✅ Đã hoàn thành Cài đặt và cấu hình.
- ✅ Đã đọc Ví dụ Instance. Các ví dụ Security Group và Floating IP dùng Instance
app-server-01.
Khối dùng chung
# shared.tf
data "fptcloud_vpc" "example" {
name = "example-vpc"
}
data "fptcloud_instance" "app" {
vpc_id = data.fptcloud_vpc.example.id
name = "app-server-01"
}
Subnet
Subnet là một dải địa chỉ IP trong VPC. Instance nhận IP private từ Subnet mà nó được đặt vào. Xem thêm Tổng quan Subnet.
Subnet cho ứng dụng
Subnet loại NAT_ROUTED cho phép Instance truy cập Internet chiều đi qua NAT gateway, phù hợp cho máy chủ web và API cần tải bản vá hoặc gọi dịch vụ bên ngoài:
# subnet.tf
resource "fptcloud_subnet" "app" {
vpc_id = data.fptcloud_vpc.example.id
name = "app-subnet"
type = "NAT_ROUTED"
cidr = "10.10.1.0/24"
gateway_ip = "10.10.1.1"
}
Subnet cô lập cho cơ sở dữ liệu
Subnet loại ISOLATED không có định tuyến ra Internet. Instance bên trong chỉ giao tiếp nội bộ trong VPC, phù hợp cho cơ sở dữ liệu và cache:
# subnet.tf
resource "fptcloud_subnet" "db" {
vpc_id = data.fptcloud_vpc.example.id
name = "db-subnet"
type = "ISOLATED"
cidr = "10.10.2.0/24"
gateway_ip = "10.10.2.1"
}
Subnet có dải IP tĩnh và DNS riêng
Dùng static_ip_pool để dành một dải địa chỉ cho cấp phát tĩnh, và primary_dns_ip, secondary_dns_ip để chỉ định máy chủ DNS:
# subnet.tf
resource "fptcloud_subnet" "internal" {
vpc_id = data.fptcloud_vpc.example.id
name = "internal-subnet"
type = "NAT_ROUTED"
cidr = "10.10.3.0/24"
gateway_ip = "10.10.3.1"
static_ip_pool = "10.10.3.100-10.10.3.200"
primary_dns_ip = "10.10.0.10"
secondary_dns_ip = "10.10.0.11"
}
static_ip_pool viết theo dạng <địa chỉ đầu>-<địa chỉ cuối>, không có khoảng trắng, và nằm trong cidr.
Nhiều Subnet từ một dải địa chỉ
Hàm cidrsubnet() chia một dải lớn thành các dải /24, giúp bạn không phải tính địa chỉ thủ công:
# subnets.tf
locals {
base_cidr = "10.20.0.0/16"
tiers = { web = 1, app = 2, db = 3 }
}
resource "fptcloud_subnet" "tier" {
for_each = local.tiers
vpc_id = data.fptcloud_vpc.example.id
name = "${each.key}-subnet"
type = each.key == "db" ? "ISOLATED" : "NAT_ROUTED"
cidr = cidrsubnet(local.base_cidr, 8, each.value)
gateway_ip = cidrhost(cidrsubnet(local.base_cidr, 8, each.value), 1)
}
Cấu hình trên tạo web-subnet (10.20.1.0/24), app-subnet (10.20.2.0/24) và db-subnet (10.20.3.0/24).
Dải CIDR của Subnet không được chồng lấn với Subnet khác trong VPC, và gateway_ip phải nằm trong dải CIDR. Đổi name, type, cidr, gateway_ip hoặc static_ip_pool sẽ tạo lại Subnet, kéo theo tạo lại mọi Instance trong Subnet đó.
Security Group
Security Group là tường lửa ảo kiểm soát lưu lượng vào và ra của Instance. Lưu lượng không khớp với rule nào sẽ bị từ chối. Xem thêm Tổng quan Security Group.
Tham số type là bắt buộc khi tạo Security Group. Đặt type = "ACL".
Security Group cho máy chủ web
Ví dụ dưới đây cho phép HTTP và HTTPS từ mọi nơi, và SSH chỉ từ mạng văn phòng. Security Group được gắn vào Instance qua tham số apply_to, nhận danh sách IP private của các Instance cần bảo vệ:
# security.tf
resource "fptcloud_security_group" "web" {
vpc_id = data.fptcloud_vpc.example.id
name = "web-sg"
subnet_id = fptcloud_subnet.app.id
type = "ACL"
apply_to = [data.fptcloud_instance.app.private_ip]
}
# security.tf
locals {
web_rules = {
http = { port = "80", source = "ALL" }
https = { port = "443", source = "ALL" }
ssh = { port = "22", source = "203.0.113.0/24" } # Mạng văn phòng của bạn
}
}
# security.tf
resource "fptcloud_security_group_rule" "web" {
for_each = local.web_rules
vpc_id = data.fptcloud_vpc.example.id
security_group_id = fptcloud_security_group.web.id
direction = "INGRESS"
action = "ALLOW"
protocol = "TCP"
port_range = each.value.port
sources = [each.value.source]
description = "Allow ${each.key}"
}
Dùng map với for_each giúp bạn thêm hoặc bớt rule mà không ảnh hưởng các rule còn lại.
Security Group cho cơ sở dữ liệu
Chỉ cho phép máy chủ ứng dụng kết nối tới PostgreSQL (cổng 5432), với nguồn là dải CIDR của Subnet ứng dụng:
# security.tf
data "fptcloud_instance" "db" {
vpc_id = data.fptcloud_vpc.example.id
name = "db-server-01"
}
resource "fptcloud_security_group" "db" {
vpc_id = data.fptcloud_vpc.example.id
name = "db-sg"
subnet_id = fptcloud_subnet.db.id
type = "ACL"
apply_to = [data.fptcloud_instance.db.private_ip]
}
# security.tf
resource "fptcloud_security_group_rule" "postgres" {
vpc_id = data.fptcloud_vpc.example.id
security_group_id = fptcloud_security_group.db.id
direction = "INGRESS"
action = "ALLOW"
protocol = "TCP"
port_range = "5432"
sources = [fptcloud_subnet.app.cidr]
description = "PostgreSQL from the app subnet"
}
Một Security Group cho nhiều Instance
Đưa IP private của tất cả Instance cần bảo vệ vào apply_to. Ví dụ dưới đây lấy IP của mọi Instance có tên bắt đầu bằng web-server-. Danh sách được đọc lại mỗi lần chạy terraform apply, nên Instance mới được thêm vào Security Group ở lần apply tiếp theo:
# security.tf
data "fptcloud_instances" "all" {
vpc_id = data.fptcloud_vpc.example.id
}
locals {
web_ips = [
for vm in data.fptcloud_instances.all.instances : vm.private_ip
if startswith(vm.name, "web-server-")
]
}
Sau đó đặt apply_to = local.web_ips cho Security Group.
Giá trị của rule
| Tham số | Giá trị |
|---|---|
direction | INGRESS cho lưu lượng vào, EGRESS cho lưu lượng ra. |
action | Luôn là ALLOW. Security Group không hỗ trợ rule chặn, lưu lượng không khớp rule nào đã bị từ chối sẵn. |
protocol | TCP, UDP, ICMP hoặc ALL. |
port_range | Một cổng ("22"), một dải cổng ("8000-8100") hoặc "ALL". Bắt buộc là "ALL" khi protocol = "ALL". |
sources | Một dải CIDR IPv4, một địa chỉ IPv4 hoặc "ALL". Với rule EGRESS, đây là địa chỉ đích. |
Mỗi rule chỉ nên có một nguồn và một cổng hoặc một dải cổng. Để mở một cổng cho nhiều nguồn, hoặc nhiều cổng cho một nguồn, hãy tạo mỗi tổ hợp một rule bằng for_each như ví dụ máy chủ web ở trên. Nếu đưa nhiều giá trị vào sources, FPT Cloud sẽ tách thành nhiều rule riêng, và terraform destroy có thể không xóa hết các rule đó.
Rule không sửa được tại chỗ. Đổi bất kỳ tham số nào của rule, kể cả description, sẽ xóa rule cũ rồi tạo rule mới. Trong khoảng thời gian ngắn giữa hai bước, lưu lượng của rule đó có thể bị chặn.
Gắn Security Group bằng apply_to
Gắn Security Group bằng apply_to của Security Group, không dùng tham số security_group_ids của Instance. security_group_ids chỉ có tác dụng khi tạo Instance, và FPT Cloud báo về cả các Security Group gắn qua apply_to, khiến plan luôn báo thay đổi.
Instance vừa tạo có thể chưa báo IP private trong thời gian ngắn. Đọc IP qua data source fptcloud_instance như trong các ví dụ trên. Nếu apply_to rỗng sau lần apply đầu tiên, chạy lại terraform apply.
Xóa Security Group
FPT Cloud chỉ xóa được Security Group khi nó không còn gắn vào tài nguyên nào. Trước khi xóa Security Group cùng các Instance của nó:
- Đặt
apply_to = []cho Security Group. - Chạy
terraform apply. - Chạy
terraform destroy.
Dựng hạ tầng ứng dụng web hoàn chỉnh có cách dùng biến để thực hiện bước này gọn hơn.
Floating IP
Floating IP là địa chỉ IP public mà bạn cấp phát độc lập rồi gán cho Instance. Vì IP không gắn chặt với Instance, bạn có thể chuyển IP sang Instance khác mà không đổi cấu hình DNS. Xem thêm Tổng quan Floating IP.
Cấp phát và gán Floating IP
# public-ip.tf
resource "fptcloud_floating_ip" "app" {
vpc_id = data.fptcloud_vpc.example.id
}
resource "fptcloud_floating_ip_association" "app" {
vpc_id = data.fptcloud_vpc.example.id
floating_ip_id = fptcloud_floating_ip.app.id
instance_id = data.fptcloud_instance.app.id
}
output "public_ip" {
value = fptcloud_floating_ip.app.ip_address
}
fptcloud_floating_ip giữ địa chỉ IP, còn fptcloud_floating_ip_association gán địa chỉ đó cho Instance. Tách thành hai resource giúp địa chỉ IP không đổi khi bạn chuyển nó sang Instance khác.
Chuyển Floating IP sang Instance khác
Đổi instance_id của fptcloud_floating_ip_association sẵn có rồi chạy terraform apply. Terraform gỡ IP khỏi Instance cũ và gán cho Instance mới, địa chỉ IP vẫn giữ nguyên:
data "fptcloud_instance" "standby" {
vpc_id = data.fptcloud_vpc.example.id
name = "app-server-02"
}
resource "fptcloud_floating_ip_association" "app" {
vpc_id = data.fptcloud_vpc.example.id
floating_ip_id = fptcloud_floating_ip.app.id
instance_id = data.fptcloud_instance.standby.id # trước đây là data.fptcloud_instance.app.id
}
Mỗi Floating IP chỉ nên có một fptcloud_floating_ip_association. Khi chuyển IP, sửa resource sẵn có thay vì tạo thêm resource mới.
Gán Floating IP bằng fptcloud_floating_ip_association thay vì tham số public_ip của Instance. public_ip chỉ có tác dụng khi tạo Instance, nên không dùng được để chuyển hoặc gỡ IP sau này.