Chuyển tới nội dung chính

Ví dụ tag

Tag giúp bạn phân loại tài nguyên theo dự án, môi trường hoặc nhóm sở hữu, từ đó theo dõi chi phí và áp dụng chính sách dễ dàng hơn. Với Terraform, bạn tạo tag một lần rồi gắn cho mọi tài nguyên trong cấu hình, nên không bao giờ quên gắn tag cho tài nguyên mới. Khái niệm về tag xem tại FPT Cloud Tagging.

Điều kiện tiên quyết​

Gắn tag gồm hai bước​

  1. Tạo tag bằng resource fptcloud_tagging.
  2. Đưa ID của tag vào tham số tag_ids của từng tài nguyên.

Các resource nhận tag_ids trong phần hướng dẫn này: fptcloud_instance, fptcloud_storage, fptcloud_subnet, fptcloud_security_group, fptcloud_floating_ip và fptcloud_snapshot.

Tạo tag​

# tags.tf
resource "fptcloud_tagging" "env_production" {
key = "environment"
value = "production"
color = "#057a55"
scope_type = "ORG"
}

resource "fptcloud_tagging" "team_payments" {
key = "team"
value = "payments"
scope_type = "ORG"
}
  • key là bắt buộc, value và color là tùy chọn.
  • scope_type = "ORG" cho phép dùng tag trong toàn bộ tổ chức, giống tag tạo trên Portal.
  • color nhận một mã màu trong bảng Màu tag.

Gắn tag cho tài nguyên​

Thêm tag_ids vào các tài nguyên cần gắn tag:

# tagged.tf
data "fptcloud_vpc" "example" {
name = "example-vpc"
}

resource "fptcloud_subnet" "payments" {
vpc_id = data.fptcloud_vpc.example.id
name = "payments-subnet"
type = "NAT_ROUTED"
cidr = "10.30.1.0/24"
gateway_ip = "10.30.1.1"
tag_ids = [fptcloud_tagging.env_production.id, fptcloud_tagging.team_payments.id]
}
# tagged.tf
resource "fptcloud_floating_ip" "payments" {
vpc_id = data.fptcloud_vpc.example.id
tag_ids = [fptcloud_tagging.env_production.id, fptcloud_tagging.team_payments.id]
}

Với Instance và disk, thêm cùng dòng tag_ids vào khối fptcloud_instance hoặc fptcloud_storage. Tag được cập nhật tại chỗ, nên thêm hoặc bớt tag không làm tạo lại tài nguyên.

Gắn một bộ tag chung cho mọi tài nguyên​

Khai báo bộ tag chung trong locals, rồi dùng lại ở mọi tài nguyên. Khi cần thêm tag, bạn chỉ sửa một chỗ:

# common-tags.tf
locals {
common_tag_ids = [
fptcloud_tagging.env_production.id,
fptcloud_tagging.team_payments.id,
]
}

Sau đó đặt tag_ids = local.common_tag_ids cho từng tài nguyên.

Tạo nhiều tag từ một map​

# tags-map.tf
locals {
tags = {
environment = "staging"
project = "online-shop"
cost-center = "cc-1024"
}
}

resource "fptcloud_tagging" "this" {
for_each = local.tags

key = each.key
value = each.value
scope_type = "ORG"
}

Lấy danh sách ID bằng [for t in fptcloud_tagging.this : t.id].

Dùng lại tag có sẵn​

Nếu tag đã được tạo trên Portal, đọc tag bằng data source thay vì tạo lại:

# existing-tag.tf
data "fptcloud_tagging" "owner" {
key = "owner"
value = "platform-team"
}

Dùng data.fptcloud_tagging.owner.tags[0].id trong tag_ids.

Màu tag​

MàuGiá trị color
Gray#4b5563
Red#c81e1e
Orange#d03801
Yellow#dc6803
Green#057a55
Teal#047481
Indigo#5850ec
Purple#6c2bd9
Sky blue#00bfff

Giá trị không phân biệt chữ hoa và chữ thường. Bỏ trống color để tạo tag không màu.

Bước tiếp theo​